易語言源碼包

Ⅰ 怎麼查看易語言源碼

您朋友發的恐怕就是後綴為.e的易語言源碼吧，這樣的話，直接安裝易語言即可打開了。

Ⅱ 易語言源碼工具箱源碼

製作方案:
准備一個要載入工具箱的exe
新建個易語言程序，進入易語言-插入-資源-圖片或圖片組
將圖片1改為exe
雙擊內容
導入新圖片
然後載入exe
回到啟動窗口，新建個按鈕，按鈕輸入代碼:
寫到文件("D:\臨時調試文件.exe",#exe)
運行("D:\臨時調試文件.exe")
刪除文件("D:\臨時調試文件.exe")
然後調試程序,點擊那個按鈕,你會發現剛才載入的exe運行了！

Ⅲ 易語言安裝包怎麼寫有源碼發個 最好幫忙寫個

寫出一個完整的安裝包是復雜的，包括：
你在易語言上編寫一個安裝包/卸載包界面
它里邊已經有寫解壓命令
生成安裝信息到注冊表
完成後生成卸載程序
對常規配置進行編寫後寫入到帶模板exe，(這些配置有:添加欲壓縮的文件/文件夾，版權信息，同意條款界面，安裝密碼，以及安裝之後要執行的程序/文件配置，生成快捷方式等.

然後將已壓的壓縮包與易語言的配置模板進行捆綁生成一個自解壓包exe.

所以一般不會有人幫你寫，但在易語言吧里，一位好人正在努力編寫。將在：
大年初一將7z/rar解壓/壓縮模塊與這個安裝包集成編寫配置的工具一起開源給大家了。

參考：http://tieba..com/p/2821348694?pid=44641447124&cid=0#44641447124
參考：http://tieba..com/p/2826834624?pid=44821796349&cid=44833981277#44833981277

Ⅳ 新手求解網上下載的易語言源碼怎麼使用

你有可能是 沒有 把那個 源碼 解壓！ 先 把那個包 解壓到桌面 然後再打開試試 應該可以了 或者你這個 易語言版本問題 重新下載一個 試試 推薦使用完整版 破解版都 不太穩定

Ⅳ 易語言發送封包源碼

哦，如果是使用TCP協議的話使用組件- 客戶 .版本 2.如果真 (客戶1.連接 (「要發送的ip」, 埠號) ＝ 真)
客戶1.發送數據 (這里是通用型,直接把數據包保存的文件發送出去。建議把數據包保存為一個文件再發送)
返回 (真)
.如果真結束
信息框 (「連接失敗」, 0, )
返回 (假)
如果是udp協議使用數據報 組件源碼類同
以上回答你滿意么？

Ⅵ 易語言源碼

哦 哦 ，那我給你個記事本的源碼吧 如下
.版本 2
.支持庫 iext2
.支持庫 iext
.支持庫 eAPI

.程序集 窗口程序集1
.程序集變數 文件路徑, 文本型
.程序集變數 當前是否正在打字, 邏輯型

.子程序 _超級編輯框1_內容被改變, , , 更改超級編輯框的顏色
.局部變數 顏色, 字元格式

顏色.文本顏色 ＝ 取顏色值 (取隨機數 (0, 255), 取隨機數 (0, 255), 取隨機數 (0, 255))
超級編輯框1.置選擇區字元格式 (顏色)
狀態條1.置文本 (0, 「行 」 ＋ 到文本 (超級編輯框1.取行數 ()) ＋ 「 文本長度 」 ＋ 到文本 (超級編輯框1.取文本長度 ()))

.子程序 __啟動窗口_創建完畢, , , 設置通用對話框

通用對話框1.過濾器 ＝ 「txt|*.txt」
通用對話框1.默認文件後綴 ＝ 「txt」
通用對話框1.標題 ＝ 「傳說記事本保存對話框...」
_時間日期_被選擇 ()
_炫銀皮膚_被選擇 ()
備忘錄提醒 ()

.子程序 __啟動窗口_位置被改變, , , 位置被改變後超級編輯框也跟著改變(按鈕1也跟著改變)

.如果真 (_啟動窗口.位置 ＝ 3)
超級編輯框1.寬度 ＝ 取屏幕寬度 () － 3
超級編輯框1.高度 ＝ 取屏幕高度 () － 80 － 按鈕1.高度 － 10
按鈕1.頂邊 ＝ 取屏幕高度 () － 狀態條1.高度 － 100
按鈕1.寬度 ＝ 取屏幕寬度 () － 5
按鈕1.高度 ＝ 狀態條1.高度 ＋ 10
.如果真結束
.如果真 (_啟動窗口.位置 ＝ 0)
超級編輯框1.寬度 ＝ _啟動窗口.寬度 － 10
超級編輯框1.高度 ＝ _啟動窗口.高度 － 55 － 按鈕1.高度 － 10
按鈕1.頂邊 ＝ 200
按鈕1.寬度 ＝ 560

.如果真結束

.子程序 _新建_被選擇, , , New文件

.如果真 (超級編輯框1.內容 ≠ 「」)
.如果真 (信息框 (「您還沒保存!請問您要進行保存嗎?」, 4, ) ＝ #是鈕)
通用對話框1.類型 ＝ 1
通用對話框1.打開 ()
寫到文件 (通用對話框1.文件名, 到位元組集 (超級編輯框1.內容))
.如果真結束

.如果真結束

.子程序 _打開_被選擇, , , Open文件

通用對話框1.類型 ＝ 0
通用對話框1.打開 ()
.如果真 (通用對話框1.文件名 ≠ 「」)
超級編輯框1.內容 ＝ 到文本 (讀入文件 (通用對話框1.文件名))
文件路徑 ＝ 通用對話框1.文件名

.如果真結束

.子程序 _保存_被選擇, , , Save文件

.如果真 (文件路徑 ＝ 「」)
通用對話框1.類型 ＝ 1
通用對話框1.打開 ()
寫到文件 (通用對話框1.文件名, 到位元組集 (超級編輯框1.內容))
.如果真結束
.如果真 (文件路徑 ≠ 「」)
寫到文件 (文件路徑, 到位元組集 (超級編輯框1.內容))
.如果真結束

.子程序 _保存到_被選擇, , , Save As文件

通用對話框1.類型 ＝ 1
通用對話框1.打開 ()
.如果真 (通用對話框1.文件名 ≠ 「」)
寫到文件 (通用對話框1.文件名, 到位元組集 (超級編輯框1.內容))
.如果真結束

.子程序 _撤銷_被選擇, , , Undo 文本

超級編輯框1.撤消 ()

.子程序 _剪切_被選擇, , , Cut 文本

超級編輯框1.剪切 ()

.子程序 _復制_被選擇, , , Copy 文本

超級編輯框1.復制 ()

.子程序 _粘連_被選擇, , , Paste文本

超級編輯框1.粘貼 ()

.子程序 _刪除_被選擇, , , Delete文本

超級編輯框1.刪除 ()
超級編輯框1.內容 ＝ 取文本左邊 (超級編輯框1.內容, 取文本長度 (超級編輯框1.內容) － 1)

.子程序 _尋找_被選擇, , , Find文本

載入 (Find窗口, , 真)

.子程序 _尋找下一個_被選擇, , , 還沒解決好

.子程序 _文本替換_被選擇, , , 文本替換

載入 (文本替換窗口, , 真)

.子程序 _跳到_被選擇, , , 還沒解決好

載入 (跳到窗口, , 真)

.子程序 _全選_被選擇, , , Select All文本

超級編輯框1.被選擇字元數 ＝ 取文本長度 (超級編輯框1.內容)

.子程序 _時間日期_被選擇, , , Time-Date
.局部變數 小時, 文本型
.局部變數 分鍾, 文本型
.局部變數 日期, 文本型
.局部變數 年份, 文本型
.局部變數 月份, 文本型
.局部變數 日份, 文本型

小時 ＝ 到文本 (取小時 (取現行時間 ()))
分鍾 ＝ 到文本 (取分鍾 (取現行時間 ()))
年份 ＝ 到文本 (取年份 (取現行時間 ()))
月份 ＝ 到文本 (取月份 (取現行時間 ()))
日份 ＝ 到文本 (取日 (取現行時間 ()))
狀態條1.置文本 (1, 小時 ＋ 「:」 ＋ 分鍾 ＋ 「 」 ＋ 年份 ＋ 「-」 ＋ 月份 ＋ 「-」 ＋ 日份)

.子程序 _傳說記事本v13_被選擇, , , About Notepad

信息框 (「軟體作者:古老的傳說」 ＋ #換行符 ＋ 「QQ:1041750677」 ＋ #換行符 ＋ 「MSN:[email protected]」 ＋ #換行符 ＋ 「編寫工具:易語言」 ＋ #換行符 ＋ 「軟體版本:1.3」 ＋ #換行符, 0, )

.子程序 _密碼保管_被選擇, , , Password Protect

載入 (密碼窗口, , 真)

.子程序 _備忘錄_被選擇, , , 載入備忘錄窗口

載入 (備忘錄窗口, , 真)

.子程序 備忘錄提醒, , , 備忘錄提醒
.局部變數 分割文本, 文本型, , "0"
.局部變數 今天日期, 文本型
.局部變數 分割今天日期, 文本型, , "0"

分割文本 ＝ 分割文本 (讀配置項 (取運行目錄 () ＋ 「\備忘錄.ini」, 「備忘錄」, 「提示日期」, ), 「日」, )
今天日期 ＝ 到文本 (取日期 (取現行時間 ()))
分割今天日期 ＝ 分割文本 (今天日期, 「日」, )
.如果真 (取數組成員數 (分割文本) ＝ 1 或 取數組成員數 (分割文本) ＞ 1)
.如果真 (分割文本 [1] ＝ 分割今天日期 [1])
狀態條1.置文本 (2, 「您今天有一份備忘錄噢^_^」)
.如果真結束

.如果真結束

.子程序 _銀白皮膚_被選擇, , , 銀白皮膚

更換新皮膚 (1)

.子程序 _淺白皮膚_被選擇, , , 淺白皮膚

更換新皮膚 (10)

.子程序 _淺灰皮膚_被選擇, , , 淺灰皮膚

更換新皮膚 (13)

.子程序 _淺藍皮膚_被選擇, , , 淺藍皮膚

更換新皮膚 (19)

.子程序 _淺黑皮膚_被選擇, , , 淺黑皮膚

更換新皮膚 (5)

.子程序 _炫銀皮膚_被選擇, , , 炫銀皮膚

更換新皮膚 (2)

.子程序 _炫白皮膚_被選擇, , , 炫白皮膚

更換新皮膚 (15)

.子程序 _炫藍皮膚_被選擇, , , 炫藍皮膚

更換新皮膚 (18)

.子程序 _深黑皮膚_被選擇, , , 深黑皮膚

更換新皮膚 (14)

.子程序 __啟動窗口_可否被關閉, 邏輯型, , 透明顯示最小化運行
.局部變數 變數1, 整數型

變數1 ＝ 255
.計次循環首 (255, )
設置窗口透明度 (_啟動窗口.取窗口句柄 (), 變數1)
變數1 ＝ 變數1 － 1
.如果真 (變數1 ＝ 1)
置托盤圖標 (#程序圖標, 「古老的傳說記事本v1.2」)
_啟動窗口.可視 ＝ 假
.如果真結束

.計次循環尾 ()

返回 (假)

.子程序 __啟動窗口_托盤事件, , , 透明顯示_啟動窗口
.參數 操作類型, 整數型
.局部變數 變數1, 整數型

.如果真 (操作類型 ＝ 1)
_啟動窗口.可視 ＝ 真
.計次循環首 (255, 變數1)
設置窗口透明度 (_啟動窗口.取窗口句柄 (), 變數1)
.計次循環尾 ()
.如果真結束
.如果真 (操作類型 ＝ 3)
彈出菜單 (圖標菜單, 取滑鼠水平位置 (), 取滑鼠垂直位置 ())

.如果真結束

.子程序 __啟動窗口_將被銷毀, , , 銷毀任務欄圖標

置托盤圖標 ({ }, )

.子程序 _打開傳說記事本_被選擇, , , _啟動窗口.可視=真

__啟動窗口_托盤事件 (1)

.子程序 _銷毀_被選擇, , , 銷毀軟體

銷毀 ()

.子程序 _超級編輯框1_按下某鍵, 邏輯型, , 正在打字中...
.參數 鍵代碼, 整數型
.參數 功能鍵狀態, 整數型

當前是否正在打字 ＝ 真
按鈕1.標題 ＝ 「正在打字中...」
時鍾1.時鍾周期 ＝ 800
返回 (真)

.子程序 _超級編輯框1_放開某鍵, 邏輯型, , 暫停打字中...
.參數 鍵代碼, 整數型
.參數 功能鍵狀態, 整數型

當前是否正在打字 ＝ 假
返回 (真)

.子程序 _時鍾1_周期事件, , , 暫停打字中...

.如果真 (當前是否正在打字 ＝ 假)
按鈕1.標題 ＝ 「暫停打字中...」

.如果真結束

.子程序 _超級編輯框1_選擇區被改變, , , 超級編輯框1.滾動

超級編輯框1.滾動 (1)