控制演算法高手
① 單片機用PID控制可控硅，讓電烤箱溫度恆定的演算法請教高手！
pid位置式演算法，在溫度比設定溫度低x度時，用pd，當比設定溫度低x度以內，用pid。
可控硅部分，硬體用BTA26或者BT139（看加熱器件的功率了），採用過零檢測來確定過零點，用單片機的外部中斷配合tmer，來控制開關時間。在pd和pid階段，pid參數可能要用2套參數，自己實驗吧，還有，你可以看一下，Ziegler-Nichols參數整定法。
另：
OURAVR上也有個酷貼，很詳細的，你可以參考一下，網址再下面：
http://www.ourdev.cn/bbs/bbs_content.jsp?bbs_sn=936512&bbs_page_no=1&search_mode=1&search_text=pid&bbs_id=1000
② 誰可以簡單告訴我，在溫度控制中增量式PID控制演算法起什麼作用
位置式PID計算出來的就是應該輸出的控制量。
增量式PID計算出來的還要加上當前正在輸出的控制量來確定新的控制量。
③ 哪位高手可以給一份用匯編語言編寫的增量型PID演算法的程序，謝謝
;********增量式PID控制演算法程序***********
;T、TD、TI、KP依次從30H，33H，36H，39H開始。
;A，B，C的值依次存在BLOCK1，BLOCK2，BLOCK3的地址里
; 這里R(k)給的是定值
ORG 0000H
BLOCK1 EQU 43H ;A,B ,C
BLOCK2 EQU 46H
BLOCK3 EQU 49H
UK EQU 4CH ;存結果UK
RK EQU 50H
EK EQU 53H ;存放偏差值E(k)的始址
EK1 EQU 56H ;存放E(k-1)的始址
EK2 EQU 59H ;存放E(k-2)的始址
CK EQU 5CH ;采樣數據始址
BUFF EQU 60H ;暫存區
BUFF1 EQU 63H
BUFF2 EQU 66H
REC EQU 69H
TEST:
MOV RK,#01H ;常數Rk的BCD碼浮點數
MOV RK+1,#12H ;1.25
MOV RK+2,#50H
MOV 3CH,#01H ;常數1的BCD碼浮點數
MOV 3DH,#10H
MOV 3EH,#00H
MOV 40H,#01H ;常數2的BCD碼浮點數
MOV 41H,#20H
MOV 42H,#00H
MOV 30H,#01H ;T的BCD 碼浮點數
MOV 31H,#23H ;2.34
MOV 32H,#40H
MOV 33H,#01H ;Td的BCD碼浮點數
MOV 34H,#35H ;3.54
MOV 35H,#40H
MOV 36H,#01H ;Ti的BCD碼浮點數
MOV 37H,#11H ;1.12
MOV 38H,#20H
MOV 39H,#01H ;Kp的BCD碼浮點數
MOV 3AH,#12H ;1.25
MOV 3BH,#50H
MOV R0,#RK ;指向BCD碼浮點操作數
LCALL BTOF ;將其轉換成二進制浮點操作數
MOV R0,#3CH
LCALL BTOF
MOV R0,#40H
LCALL BTOF
MOV R0,#39H
LCALL BTOF
MOV R0,#36H ;指向BCD碼浮點操作數Ti
LCALL BTOF ;將其轉換成二進制浮點操作數
MOV R0,#33H ;指向BCD碼浮點操作數Td
LCALL BTOF ;將其轉換成二進制浮點操作數
MOV R0,#30H ;指向BCD碼浮點操作數T
LCALL BTOF ;將其轉換成二進制浮點操作數
MOV R1, #BUFF1 ;保存30H中的值 即T值
LCALL FMOVR0
MOV R1, #36H ;計算A值(1+T/Ti+Td/T).Kp
LCALL FDIV
MOV R1,#3CH ;常數1
LCALL FADD
MOV R0,#33H ;保存33H中的值
MOV R1,#BUFF
LCALL FMOVR0
MOV R1,#BUFF1
LCALL FDIV
MOV R1,#30H ;30H里存的是T/Ti+1
LCALL FADD
MOV R1,#39H
LCALL FMUL
MOV R1 ,#BLOCK1 ;將結果保存在BLOCK1中
LCALL FMOVR0
MOV R1,#BUFF1 ;30H恢復原值
MOV R0,#30H
LCALL FMOV
MOV R1,#BUFF ;33H恢復原值
MOV R0,#33H
LCALL FMOV
MOV R0,#40H ;計算B的值Kp.(1+2.Td/T)
MOV R1,#33H
LCALL FMUL
MOV R1,#30H
LCALL FDIV
MOV R1,#3CH
LCALL FADD
MOV R1,#39H
LCALL FMUL
MOV R1,#BLOCK2 ;保存B值到BLOCK2中
LCALL FMOVR0
MOV R0,#39H ;計算C的值Kp.Td/T
MOV R1,#33H
LCALL FMUL
MOV R1,#30H
LCALL FDIV
MOV R1,#BLOCK3 ;保存C值到BLOCK3中
LCALL FMOVR0
MOV R0,#EK1 ;將EK1，EK2設初值0
LCALL FCLR
MOV R0,#EK2
LCALL FCLR
MOV REC,#03H ;設置采樣次數
LOOP: MOV CK,#7eH ;采樣數據暫時給了一個定值
MOV CK+1,#21H ;0.002112
MOV CK+2,#12H
MOV R0,#CK
LCALL BTOF
MOV R0,#RK ;保存R（k）中的值
MOV R1,#BUFF
LCALL FMOVR0
MOV R1,#CK
LCALL FSUB ;計算R(k)-C(k)的值送給E（k）
MOV R1,#EK
LCALL FMOVR0
MOV R1,#BUFF ;恢復RK的值 釋放BUFF
MOV R0,#RK
LCALL FMOV
MOV R0,#BLOCK2 ;將B.e(k-1)的值暫存在BUFF1中
MOV R1,#BUFF ;保存B
LCALL FMOVR0
MOV R1,#EK1
LCALL FMUL
MOV R1,#BUFF1
LCALL FMOVR0
MOV R1,#BUFF ;恢復B釋放BUFF
LCALL FMOV
MOV R0,#BLOCK3 ;將C.e(K-2)的值暫存在BUFF2中
MOV R1,#BUFF ;保存C
LCALL FMOVR0
MOV R1,#EK2
LCALL FMUL
MOV R1,#BUFF2
LCALL FMOVR0
MOV R1,#BUFF ;恢復C釋放BUFF
LCALL FMOV
MOV R0,#BLOCK1 ;A.E(k)
MOV R1,#BUFF
LCALL FMOVR0
MOV R1,#EK
LCALL FMUL
MOV R1,#BUFF1 ;計算Uk值A.E(k)-B.E(k-1)+C.E(k-2)
LCALL FSUB
MOV R1,#BUFF2
LCALL FADD
MOV R1,#UK ;保存結果到UK中
LCALL FMOVR0
MOV R1,#BUFF ;恢復A 釋放BUFF
LCALL FMOV
MOV R0,#UK ;UK轉換成BCD碼浮點數輸出
LCALL FTOB
MOV R1,#EK1 ;將E(k-1)-->E(k-2),E(k)-->E(k-1)
MOV R0,#EK2
LCALL FMOV
MOV R1,#EK
MOV R0,#EK1
LCALL FMOV
LCALL DELAY ;等待采樣時刻
DJNZ REC,NEXT1
SJMP $
NEXT1: LJMP LOOP
DELAY: MOV R7,#02H
DELAY1: MOV R6,#0FFH
DELAY2: DJNZ R6,DELAY2
DJNZ R7,DELAY1
RET
; （1） 標號： FSDT 功能：浮點數格式化
;入口條件：待格式化浮點操作數在[R0]中。
;出口信息：已格式化浮點操作數仍在[R0]中。
;影響資源：PSW、A、R2、R3、R4、位1FH 堆棧需求： 6位元組
FSDT: LCALL MVR0 ;將待格式化操作數傳送到第一工作區中
LCALL RLN ;通過左規完成格式化
LJMP MOV0 ;將已格式化浮點操作數傳回到[R0]中
; （2） 標號： FADD 功能：浮點數加法
;入口條件：被加數在[R0]中，加數在[R1]中。
;出口信息：OV=0時，和仍在[R0]中，OV=1時，溢出。
;;影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求： 6位元組
FADD: CLR F0 ;設立加法標志
SJMP AS ;計算代數和
; （3） 標號： FSUB 功能：浮點數減法
;入口條件：被減數在[R0]中，減數在[R1]中。
;出口信息：OV=0時，差仍在[R0]中，OV=1時，溢出。
;影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：6位元組
FSUB: SETB F0 ;設立減法標志
AS: LCALL MVR1 ;計算代數和。先將[R1]傳送到第二工作區
MOV C,F0 ;用加減標志來校正第二操作數的有效符號
CLR A ; ********？？？應加的一條語句
RRC A
XRL A,@R1
MOV C,ACC.7
ASN: MOV 1EH,C ;將第二操作數的有效符號存入位1EH中
XRL A,@R0 ;與第一操作數的符號比較
RLC A
MOV F0,C ;保存比較結果
LCALL MVR0 ;將[R0]傳送到第一工作區中
LCALL AS1 ;在工作寄存器中完成代數運算
MOV0: INC R0 ;將結果傳回到[R0]中的子程序入口
INC R0
MOV A,R4 ;傳回尾數的低位元組
MOV @R0,A
DEC R0
MOV A,R3 ;傳回尾數的高位元組
MOV @R0,A
DEC R0
MOV A,R2 ;取結果的階碼
MOV C,1FH ;取結果的數符
MOV ACC.7,C ;拼入階碼中
MOV @R0,A
CLR ACC.7 ;不考慮數符
CLR OV ;清除溢出標志
CJNE A,#3FH,MV01;階碼是否上溢？ ******** 應為#40H
SETB OV ;設立溢出標志
MV01: MOV A,@R0 ;取出帶數符的階碼
RET
MVR0: MOV A,@R0 ;將[R0]傳送到第一工作區中的子程序
MOV C,ACC.7 ;將數符保存在位1FH中
MOV 1FH,C
MOV C,ACC.6 ;將階碼擴充為8bit補碼
MOV ACC.7,C
MOV R2,A ;存放在R2中
INC R0
MOV A,@R0 ;將尾數高位元組存放在R3中
MOV R3,A ;
INC R0
MOV A,@R0 ;將尾數低位元組存放在R4中
MOV R4,A
DEC R0 ;恢復數據指針
DEC R0
RET
MVR1: MOV A,@R1 ;將[R1]傳送到第二工作區中的子程序
MOV C,ACC.7 ;將數符保存在位1EH中
MOV 1EH,C
MOV C,ACC.6 ;將階碼擴充為8bit補碼
MOV ACC.7,C
MOV R5,A ;存放在R5中
INC R1
MOV A,@R1 ;將尾數高位元組存放在R6中
MOV R6,A
INC R1
MOV A,@R1 ;將尾數低位元組存放在R7中
MOV R7,A
DEC R1 ;恢復數據指針
DEC R1
RET
AS1: MOV A,R6 ;讀取第二操作數尾數高位元組
ORL A,R7
JZ AS2 ;第二操作數為零，不必運算
MOV A,R3 ;讀取第一操作數尾數高位元組
ORL A,R4
JNZ EQ
MOV A,R6 ;第一操作數為零，結果以第二操作數為准
MOV R3,A
MOV A,R7
MOV R4,A
MOV A,R5
MOV R2,A
MOV C,1EH
MOV 1FH,C
AS2: RET
EQ: MOV A,R2 ;對階，比較兩個操作數的階碼
XRL A,R5
JZ AS4 ;階碼相同，對階結束
JB ACC.7,EQ3;階符互異
MOV A,R2 ;階符相同，比較大小
CLR C
SUBB A,R5
JC EQ4
EQ2: CLR C ;第二操作數右規一次
MOV A,R6 ;尾數縮小一半
RRC A
MOV R6,A
MOV A,R7
RRC A
MOV R7,A
INC R5 ;階碼加一
ORL A,R6 ;尾數為零否？
JNZ EQ ;尾數不為零，繼續對階
MOV A,R2 ;尾數為零，提前結束對階
MOV R5,A
SJMP AS4
EQ3: MOV A,R2 ;判斷第一操作數階符
JNB ACC.7,EQ2;如為正，右規第二操作數
EQ4: CLR C
LCALL RR1 ;第一操作數右規一次
ORL A,R3 ;尾數為零否？
JNZ EQ ;不為零，繼續對階
MOV A,R5 ;尾數為零，提前結束對階
MOV R2,A
AS4: JB F0,AS5 ;尾數加減判斷
MOV A,R4 ;尾數相加
ADD A,R7
MOV R4,A
MOV A,R3
ADDC A,R6
MOV R3,A
JNC AS2
LJMP RR1 ;有進位，右規一次
AS5: CLR C ;比較絕對值大小
MOV A,R4
SUBB A,R7
MOV B,A
MOV A,R3
SUBB A,R6
JC AS6
MOV R4,B ;第一尾數減第二尾數
MOV R3,A
LJMP RLN ;結果規格化
AS6: CPL 1FH ;結果的符號與第一操作數相反
CLR C ;結果的絕對值為第二尾數減第一尾數
MOV A,R7
SUBB A,R4
MOV R4,A
MOV A,R6
SUBB A,R3
MOV R3,A
RLN: MOV A,R3 ;浮點數規格化
ORL A,R4 ;尾數為零否？
JNZ RLN1
MOV R2,#0C1H;階碼取最小值 ******？？應為#C0H
RET
RLN1: MOV A,R3
JB ACC.7,RLN2;尾數最高位為一否？
CLR C ;不為一，左規一次
LCALL RL1
SJMP RLN ;繼續判斷
RLN2: CLR OV ;規格化結束
RET
RL1: MOV A,R4 ;第一操作數左規一次
RLC A ;尾數擴大一倍
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
DEC R2 ;階碼減一
CJNE R2,#0C0H,RL1E;階碼下溢否？ ***** 應改為CJNE R2，#0BFH，RL1E；
CLR A
MOV R3,A ;階碼下溢，操作數以零計
MOV R4,A
MOV R2,#0C1H ; ******應改為MOV R2，#0C0H
RL1E: CLR OV
RET
RR1: MOV A,R3 ;第一操作數右規一次
RRC A ;尾數縮小一半
MOV R3,A
MOV A,R4
RRC A
MOV R4,A
INC R2 ;階碼加一
CLR OV ;清溢出標志
CJNE R2,#40H,RR1E;階碼上溢否？
MOV R2,#3FH ;階碼溢出
SETB OV
RR1E: RET
; （4） 標號： FMUL 功能：浮點數乘法
;入口條件：被乘數在[R0]中，乘數在[R1]中。
;出口信息：OV=0時，積仍在[R0]中，OV=1時，溢出。
;影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：6位元組
FMUL: LCALL MVR0 ;將[R0]傳送到第一工作區中
MOV A,@R0
XRL A,@R1 ;比較兩個操作數的符號
RLC A
MOV 1FH,C ;保存積的符號
LCALL MUL0 ;計算積的絕對值
LJMP MOV0 ;將結果傳回到[R0]中
MUL0: LCALL MVR1 ;將[R1]傳送到第二工作區中
MUL1: MOV A,R3 ;第一尾數為零否？
ORL A,R4
JZ MUL6
MOV A,R6 ;第二尾數為零否？
ORL A,R7
JZ MUL5
MOV A,R7 ;計算R3R4×R6R7－→R3R4
MOV B,R4
MUL AB
MOV A,B
XCH A,R7
MOV B,R3
MUL AB
ADD A,R7
MOV R7,A
CLR A
ADDC A,B
XCH A,R4
MOV B,R6
MUL AB
ADD A,R7
MOV R7,A
MOV A,B
ADDC A,R4
MOV R4,A
CLR A
RLC A
XCH A,R3
MOV B,R6
MUL AB
ADD A,R4
MOV R4,A
MOV A,B
ADDC A,R3
MOV R3,A
JB ACC.7,MUL2;積為規格化數否？ R7四捨五入
MOV A,R7 ;左規一次
RLC A
MOV R7,A
LCALL RL1
MUL2: MOV A,R7
JNB ACC.7,MUL3
INC R4
MOV A,R4
JNZ MUL3
INC R3
MOV A,R3
JNZ MUL3
MOV R3,#80H
INC R2
MUL3: MOV A,R2 ;求積的階碼
ADD A,R5
MD: MOV R2,A ;階碼溢出判斷
JB ACC.7,MUL4
JNB ACC.6,MUL6
MOV R2,#3FH ;階碼上溢，設立標志
SETB OV
RET
MUL4: JB ACC.6,MUL6
MUL5: CLR A ;結果清零（因子為零或階碼下溢）
MOV R3,A
MOV R4,A
MOV R2,#41H
MUL6: CLR OV
RET
; （5） 標號： FDIV 功能：浮點數除法
;入口條件：被除數在[R0]中，除數在[R1]中。
;出口信息：OV=0時，商仍在[R0]中，OV=1時，溢出。
;影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求： 5位元組
FDIV: INC R0
MOV A,@R0
INC R0
ORL A,@R0
DEC R0
DEC R0
JNZ DIV1
MOV @R0,#41H;被除數為零，不必運算
CLR OV
RET
DIV1: INC R1
MOV A,@R1
INC R1
ORL A,@R1
DEC R1
DEC R1
JNZ DIV2
SETB OV ;除數為零，溢出
RET
DIV2: LCALL MVR0 ;將[R0]傳送到第一工作區中
MOV A,@R0
XRL A,@R1 ;比較兩個操作數的符號
RLC A
MOV 1FH,C ;保存結果的符號
LCALL MVR1 ;將[R1]傳送到第二工作區中
LCALL DIV3 ;調用工作區浮點除法
LJMP MOV0 ;回傳結果
DIV3: CLR C ;比較尾數的大小
MOV A,R4
SUBB A,R7
MOV A,R3
SUBB A,R6
JC DIV4
LCALL RR1 ;被除數右規一次
SJMP DIV3
DIV4: CLR A ;借用R0R1R2作工作寄存器
XCH A,R0 ;清零並保護之
PUSH ACC
CLR A
XCH A,R1
PUSH ACC
MOV A,R2
PUSH ACC
MOV B,#10H ;除法運算，R3R4／R6R7－→R0R1
DIV5: CLR C
MOV A,R1
RLC A
MOV R1,A
MOV A,R0
RLC A
MOV R0,A
MOV A,R4
RLC A
MOV R4,A
XCH A,R3
RLC A
XCH A,R3
MOV F0,C
CLR C
SUBB A,R7
MOV R2,A
MOV A,R3
SUBB A,R6
ANL C,/F0
JC DIV6
MOV R3,A
MOV A,R2
MOV R4,A
INC R1
DIV6: DJNZ B,DIV5
MOV A,R6 ;四捨五入
CLR C
RRC A
SUBB A,R3
CLR A
ADDC A,R1 ;將結果存回R3R4
MOV R4,A
CLR A
ADDC A,R0
MOV R3,A
POP ACC ;恢復R0R1R2
MOV R2,A
POP ACC
MOV R1,A
POP ACC
MOV R0,A
MOV A,R2 ;計算商的階碼
CLR C
SUBB A,R5
LCALL MD ;階碼檢驗
LJMP RLN ;規格化
; （6） 標號： FCLR 功能：浮點數清零
;入口條件：操作數在[R0]中。
;出口信息：操作數被清零。
;影響資源：A 堆棧需求： 2位元組
FCLR: INC R0
INC R0
CLR A
MOV @R0,A
DEC R0
MOV @R0,A
DEC R0
MOV @R0,#41H
RET
; （7） 標號： FZER 功能：浮點數判零
;入口條件：操作數在[R0]中。
;出口信息：若累加器A為零，則操作數[R0]為零，否則不為零。
;影響資源：A 堆棧需求： 2位元組
FZER: INC R0
INC R0
MOV A,@R0
DEC R0
ORL A,@R0
DEC R0
JNZ ZERO
MOV @R0,#41H
ZERO: RET
; （8） 標號： FMOV 功能：浮點數傳送
;入口條件：源操作數在[R1]中，目標地址為[R0]。
;出口信息：[R0]=[R1]，[R1]不變。
;影響資源：A 堆棧需求： 2位元組
FMOV: INC R0
INC R0
INC R1
INC R1
MOV A,@R1
MOV @R0,A
DEC R0
DEC R1
MOV A,@R1
MOV @R0,A
DEC R0
DEC R1
MOV A,@R1
MOV @R0,A
RET
; （8.1） 標號： FMOVR0 功能：浮點數傳送
;入口條件：源操作數在[R0]中，目標地址為[R1]。
;出口信息：[R1]=[R0]，[R0]不變。
;影響資源：A 堆棧需求： 2位元組
FMOVR0: INC R1
INC R1
INC R0
INC R0
MOV A,@R0
MOV @R1,A
DEC R1
DEC R0
MOV A,@R0
MOV @R1,A
DEC R1
DEC R0
MOV A,@R0
MOV @R1,A
RET
; （24）標號： DTOF 功能：雙位元組十六進制定點數轉換成格式化浮點數
;入口條件：雙位元組定點數的絕對值在[R0]中，數符在位1FH中，整數部分的位數在A中。
;出口信息：轉換成格式化浮點數在[R0]中（三位元組）。
;影響資源：PSW、A、R2、R3、R4、位1FH 堆棧需求： 6位元組
DTOF: MOV R2,A ;按整數的位數初始化階碼
MOV A,@R0 ;將定點數作尾數
MOV R3,A
INC R0
MOV A,@R0
MOV R4,A
DEC R0
LCALL RLN ;進行規格化
LJMP MOV0 ;傳送結果到[R0]中
; （25） 標號： FTOD 功能：格式化浮點數轉換成雙位元組定點數
;入口條件：格式化浮點操作數在[R0]中。
;出口信息：OV=1時溢出，OV=0時轉換成功：定點數的絕對值在[R0]中（雙位元組），數符
;在位1FH中，F0=1 時為整數，CY=1時為一位元組整數一位元組小數，否則為純小數。
;影響資源：PSW、A、B、R2、R3、R4、位1FH 堆棧需求： 6位元組
FTOD: LCALL MVR0 ;將[R0]傳送到第一工作區
MOV A,R2
JZ FTD4 ;階碼為零，純小數
JB ACC.7,FTD4;階碼為負，純小數
SETB C
SUBB A,#10H
JC FTD1
SETB OV ;階碼大於16，溢出
RET
FTD1: SETB C
MOV A,R2
SUBB A,#8 ;階碼大於8否？
JC FTD3
FTD2: MOV B,#10H ;階碼大於8，按雙位元組整數轉換
LCALL FTD8
SETB F0 ;設立雙位元組整數標志
CLR C
CLR OV
RET
FTD3: MOV B,#8 ;按一位元組整數一位元組小數轉換
LCALL FTD8
SETB C ; 設立一位元組整數一位元組小數標志
CLR F0
CLR OV
RET
FTD4: MOV B,#0 ;按純小數轉換
LCALL FTD8
CLR OV ;設立純小數標志
CLR F0
CLR C
RET
FTD8: MOV A,R2 ;按規定的整數位數進行右規***階碼是擴展後的值
CJNE A,B,FTD9
MOV A,R3 ;將雙位元組結果傳送到[R0]中
MOV @R0,A
INC R0
MOV A,R4
MOV @R0,A
DEC R0
RET
FTD9: CLR C
LCALL RR1 ;右規一次
SJMP FTD8
; （26） 標號： BTOF 功能：浮點BCD碼轉換成格式化浮點數
;入口條件：浮點BCD碼操作數在[R0]中。
;出口信息：轉換成的格式化浮點數仍在[R0]中。
;影響資源：PSW、A、B、R2～R7、位1DH～1FH 堆棧需求：6位元組
BTOF: INC R0 ;判斷是否為零。
INC R0
MOV A,@R0
MOV R7,A
DEC R0
MOV A,@R0
MOV R6,A
DEC R0
ORL A,R7
JNZ BTF0
MOV @R0,#41H;為零，轉換結束。
RET
BTF0: MOV A,@R0
MOV C,ACC.7
MOV 1DH,C ;保存數符。
CLR 1FH ;以絕對值進行轉換。
MOV C,ACC.6 ;擴充階碼為八位。
MOV ACC.7,C
MOV @R0,A
JNC BTF1
ADD A,#19 ;是否小於1E－19？
JC BTF2
MOV @R0,#41H ;小於1E－19時以0計。
INC R0
MOV @R0,#0
INC R0
MOV @R0,#0
DEC R0
DEC R0
RET
BTF1: SUBB A,#19
JC BTF2
MOV A,#3FH ;大於1E19時封頂。
MOV C,1DH
MOV ACC.7,C
MOV @R0,A
INC R0
MOV @R0,#0FFH
INC R0
MOV @R0,#0FFH
DEC R0
DEC R0
RET
BTF2: CLR A ;准備將BCD碼尾數轉換成十六進制浮點數。
MOV R4,A
MOV R3,A
MOV R2,#10H ;至少兩個位元組。
BTF3: MOV A,R7
ADD A,R7
DA A
MOV R7,A
MOV A,R6
ADDC A,R6
DA A
MOV R6,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
DEC R2
JNB ACC.7,BTF3;直到尾數規格化。
MOV A,R6 ;四捨五入。
ADD A,#0B0H ; ******加#80H，也可以
CLR A
ADDC A,R4
MOV R4,A
CLR A
ADDC A,R3
MOV R3,A
JNC BTF4
MOV R3,#80H ; ****有進位右規一次
INC R2
BTF4: MOV DPTR,#BTFL;准備查表得到十進制階碼對應的浮點數。
MOV A,@R0
ADD A,#19 ;計算表格偏移量。
MOV B,#3
MUL AB
ADD A,DPL
MOV DPL,A
JNC BTF5
INC DPH
BTF5: CLR A ;查表。
MOVC A,@A+DPTR
MOV C,ACC.6
MOV ACC.7,C
MOV R5,A
MOV A,#1
MOVC A,@A+DPTR
MOV R6,A
MOV A,#2
MOVC A,@A+DPTR
MOV R7,A
LCALL MUL1 ;將階碼對應的浮點數和尾數對應的浮點數相乘。
MOV C,1DH ;取出數符。
MOV 1FH,C
LJMP MOV0 ;傳送轉換結果。
; （27） 標號： FTOB 功能：格式化浮點數轉換成浮點BCD碼
;入口條件：格式化浮點操作數在[R0]中。
;出口信息：轉換成的浮點BCD碼仍在[R0]中。
;影響資源：PSW、A、B、R2～R7、位1DH～1FH 堆棧需求：6位元組
FTOB: INC R0
MOV A,@R0
INC R0
ORL A,@R0
DEC R0
DEC R0
JNZ FTB0
MOV @R0,#41H
RET
FTB0: MOV A,@R0
MOV C,ACC.7
MOV 1DH,C
CLR ACC.7
MOV @R0,A
LCALL MVR0
MOV DPTR,#BFL0;絕對值大於或等於1時的查表起點。
MOV B,#0 ;十的0次冪。
MOV A,R2
JNB ACC.7,FTB1
MOV DPTR,#BTFL;絕對值小於1E－6時的查表起點。
MOV B,#0EDH ;十的－19次冪。
ADD A,#16
JNC FTB1
MOV DPTR,#BFLN;絕對值大於或等於1E－6時的查表起點。
MOV B,#0FAH ;十的－6次冪。
FTB1: CLR A ;查表，找到一個比待轉換浮點數大的整數冪。
MOVC A,@A+DPTR
MOV C,ACC.6
MOV ACC.7,C
MOV R5,A
MOV A,#1
MOVC A,@A+DPTR
MOV R6,A
MOV A,#2
MOVC A,@A+DPTR
MOV R7,A
MOV A,R5 ;和待轉換浮點數比較。
CLR C
SUBB A,R2
JB ACC.7,FTB2;差為負數。
JNZ FTB3
MOV A,R6
CLR C
SUBB A,R3
JC FTB2
JNZ FTB3
MOV A,R7
CLR C
SUBB A,R4
JC FTB2
JNZ FTB3
MOV R5,B ;正好是表格中的數。
INC R5 ;冪加一。
MOV R6,#10H ;尾數為0·1000。
MOV R7,#0
SJMP FTB6 ;傳送轉換結果。
FTB2: INC DPTR ;准備表格下一項。
INC DPTR
INC DPTR
INC B ;冪加一。
SJMP FTB1 ;
FTB3: PUSH B ;保存冪值。
LCALL DIV3 ;相除，得到一個二進制浮點數的純小數。
FTB4: MOV A,R2 ;取階碼。
JZ FTB5 ;為零嗎？
CLR C ;
LCALL RR1 ;右規。
SJMP FTB4
FTB5: POP ACC ;取出冪值。
MOV R5,A ;作為十進制浮點數的階碼。
LCALL HB2 ;轉換尾數的十分位和百分位。
MOV R6,A
LCALL HB2 ;轉換尾數的千分位和萬分位。
MOV R7,A
MOV A,R3 ;四捨五入。
RLC A
CLR A
ADDC A,R7
DA A
MOV R7,A
CLR A
ADDC A,R6
DA A
MOV R6,A
JNC FTB6
MOV R6,#10H
INC R5
FTB6: INC R0 ;存放轉換結果。
INC R0
MOV A,R7
MOV @R0,A
DEC R0
MOV A,R6
MOV @R0,A
DEC R0
MOV A,R5
MOV C,1DH ;取出數符。
MOV ACC.7,C
MOV @R0,A
RET
HB2: MOV A,R4 ; 尾數擴大100倍。
MOV B,#100
MUL AB
MOV R4,A
MOV A,B
XCH A,R3
MOV B,#100
MUL AB
ADD A,R3
MOV R3,A
JNC HB21
INC B
HB21: MOV A,B ;將整數部分轉換成BCD碼。
MOV B,#10
DIV AB
SWAP A
ORL A,B
RET
BTFL: DB 41H,0ECH,1EH ;1.0000E-19
DB 45H,93H,93H ;1.0000E-18
DB 48H,0B8H,78H ;1.0000E-17
DB 4BH,0E6H,96H ;1.0000E-16
DB 4FH,90H,1DH ;1.0000E-15
DB 52H,0B4H,25H ;1.0000E-14
DB 55H,0E1H,2EH ;1.0000E-13
DB 59H,8CH,0BDH ;1.0000E-12
DB 5CH,0AFH,0ECH ;1.0000E-11
DB 5FH,0DBH,0E7H ;1.0000E-10
DB 63H,89H,70H ;1.0000E-9
DB 66H,0ABH,0CCH ;1.0000E-8
DB 69H,0D6H,0C0H ;1.0000E-7
BFLN: DB 6DH,86H,38H ;1.0000E-6
DB 70H,0A7H,0C6H ;1.0000E-5
DB 73H,0D1H,0B7H ;1.0000E-4
DB 77H,83H,12H ;1.0000E-3
DB 7AH,0A3H,0D7H ;1.0000E-2
DB 7DH,0CCH,0CDH ;1.0000E-1
BFL0: DB 1,80H,00H ;1.0000
DB 4,0A0H,00H ;；1.0000E1
DB 7,0C8H,00H ;1.0000E2
DB 0AH,0FAH,00H ;1.0000E3
DB 0EH,9CH,40H ;1.0000E4
DB 11H,0C3H,50H ;1.0000E5
DB 14H,0F4H,24H ;1.0000E6
DB 18H,98H,97H ;1.0000E7
DB 1BH,0BEH,0BCH ;1.0000E8
DB 1EH,0EEH,6BH ;1.0000E9
DB 22H,95H,03H ;1.0000E10
DB 25H,0BAH,44H ;1.0000E11
DB 28H,0E8H,0D5H ;1.0000E12
DB 2CH,91H,85H ; 1.0000E13
DB 2FH,0B5H,0E6H ;1.0000E14
DB 32H,0E3H,60H ;1.0000E15
DB 36H,8EH,1CH ;1.0000E16
DB 39H,31H,0A3H ;1.0000E17
DB 3CH,0DEH,0BH ;1.0000E18
DB 40H,8AH,0C7H ;1.0000E19